めまぴークライアントのデモ２のソース

めまぴークライアントのデモ２の記事はこちらです。

■Application.cfm

<cfsetting enableCFoutputOnly="yes">

<!--- session有効時間は１時間 --->
<cfapplication name="memapi_demo_2_sys"
    clientmanagement="Yes"
    sessionmanagement="yes"
    loginStorage="session"
    sessiontimeout=#CreateTimeSpan(1, 0, 0, 0)# >

<!---===================================
設定
====================================--->
<cfparam name="cookie.user_id"  default="">
<cfparam name="cookie.key"      default="">
<cfparam name="session.word"    default="">
<cfparam name="session.chk"     default="">
<cfset request.user_id  = cookie.user_id>
<cfset request.key      = cookie.key>
<cfset request.word     = session.word>
<cfset request.chk      = session.chk>
<cfset request.cat_id   = 1>
<!--- 通常
<cfset request.proxyServer      = "">
<cfset request.proxyPort        = "80">
--->
<!--- 会社
<cfset request.proxyServer      = "xx.xx.xx.xx">
<cfset request.proxyPort        = "xx">
--->
<cfset request.proxyServer      = "">
<cfset request.proxyPort        = "80">
<cfset request.url              = "http://memapi.utalab.com/index.cfm?go=">

<!---
現在のサーバー時刻から
世界標準時 (UTC: Universal Time Coordinated) からの相対情報を取得し、
9時間プラスすることにより日本時間とする。
--->
<cfset info = GetTimeZoneInfo()>
<cfset UTC = DateAdd("h", info.utcHourOffset, now())>
<cfset request.now = DateAdd("h", 9, UTC)>

■index.cfm

<cfprocessingdirective pageEncoding = "UTF-8">
<!---/////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////--->
<cfparam name="url.p"       default="">
<cfparam name="url.page"    default="1">

<cfparam name="form.id"     default="">
<cfparam name="form.m1"     default="">
<cfparam name="form.i1"     default="">

<cfswitch expression = "#url.p#">
    <!--- srch --->
    <cfcase value="srch">
        <cfset session.word = form.word>
        <cfset session.chk  = form.chk>
        <cfset request.word = form.word>
        <cfset request.chk  = form.chk>
    </cfcase>
    <!--- addEnd --->
    <cfcase value="addEnd">
        <cfhttp url="#request.url#dataAddEx"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">

            <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
            <cfhttpparam type="formField" name="key"        value="#request.key#">
            <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
            <cfhttpparam type="formField" name="c1"         value="#dateformat(request.now, 'yyyy/mm/dd')#">
            <cfhttpparam type="formField" name="c2"         value="#timeformat(request.now, 'HH:mm:ss')#">
            <cfhttpparam type="formField" name="m1"         value="#form.m1#">
            <cfhttpparam type="formField" name="i1"         value="0">
        </cfhttp>
    </cfcase>
    <!--- updEnd --->
    <cfcase value="updEnd">
        <cfhttp url="#request.url#dataUpdEx"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">

            <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
            <cfhttpparam type="formField" name="key"        value="#request.key#">
            <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
            <cfhttpparam type="formField" name="id"         value="#form.id#">
            <cfhttpparam type="formField" name="i1"         value="#form.i1#">
        </cfhttp>

    </cfcase>
</cfswitch>
<cfif findnocase("end", url.p)>
    <cflocation url="index.cfm" addtoken="no">
</cfif>

<cfset st = cst_getData("", url.page)>
<cfset cst_layout(st)>
<!---=================================================================
cst_getData
==================================================================--->
<cffunction name="cst_getData" access="public" returnType="struct" output="no">
    <cfargument name="id" type="string" required="yes">
    <cfargument name="page" type="string" default="1">

    <cfhttp url         = "#request.url#dataGetEx"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">
        <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
        <cfhttpparam type="formField" name="key"        value="#request.key#">
        <cfhttpparam type="formField" name="id"         value="#arguments.id#">
        <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
        <cfhttpparam type="formField" name="fil_id"     value="c1c2_desc">
        <cfhttpparam type="formField" name="fld_list"   value="id,cat_id,c1,c2,m1,i1">
        <cfhttpparam type="formField" name="srch_fld"   value="m1">
        <cfhttpparam type="formField" name="word"       value="#request.word#">
        <cfhttpparam type="formField" name="fromto_fld" value="i1">
        <cfhttpparam type="formField" name="from"       value="#request.chk#">
        <cfhttpparam type="formField" name="to"         value="#request.chk#">
        <cfhttpparam type="formField" name="row"        value="10">
        <cfhttpparam type="formField" name="page"       value="#arguments.page#">
        <cfhttpparam type="formField" name="type"       value="wddx">
        <cfhttpparam type="formField" name="debug"      value="">
    </cfhttp>

    <cfwddx action="wddx2cfml" input="#cfhttp.filecontent#" output="outData">

    <cfreturn outdata>
</cffunction>
<!---=================================================================
cst_layout
==================================================================--->
<cffunction name="cst_layout" access="public" returnType="void" output="yes">
    <cfargument name="stru" type="struct" required="yes">

    <cfset var st = arguments.stru>

    <cfoutput>
    <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
    <html xmlns="http://www.w3.org/1999/xhtml" lang="ja" xml:lang="ja">
    <head>
        <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
        <meta http-equiv="content-style-type" content="text/css; charset=utf-8" />
        <meta http-equiv="Content-Script-Type" content="text/javascript" />
        <title>めまぴークライアントのデモ（メモ）</title>
        <meta name="keywords" content="めまぴー,memapi" />
        <meta name="description" content="めまぴークライアントのデモ（メモ）です。" />
        <link href="common.css" rel="stylesheet" type="text/css" media="all" />
        <script type="text/javascript" src="common.js"></script>
        <script type="text/javascript" src="index.js"></script>
    </head>
    <body>
    <!-- container -->
    <div id="container">

        <!-- header -->
        <div id="header">
            <!-- left -->
            <div class="left">
                        <h1><a href="index.cfm" accesskey="1">めまぴークライアントのデモ（メモ）</a></h1>
                        <h2>by <a href="http://memapi.utalab.com/" target="_blank">めまぴー</a></h2>
            <!-- /.left --></div>

            <!-- right -->
            <div class="right">
            <!-- /.right --></div>

        <!-- /##header --></div>

        <div class="clearblock"/>

        <!-- left -->
        <div id="left">
            <!-- menu -->
            <div class="menu">
                <p class="title">STATUS</p>

                <table>
                    <tr>
                        <th>ret</th>
                        <td align="right" id="ret">#st.ret#</td>
                    </tr>
                    <tr>
                        <th>pageCount</th>
                        <td align="right" id="pageCount">#st.pageCount#</td>
                    </tr>
                    <tr>
                        <th>recCount</th>
                        <td align="right" id="recCount">#st.recCount#</td>
                    </tr>
                </table>

            <!-- /.menu --></div>

            <!-- menu -->
            <div class="menu">
                <p class="title">検索</p>

                <form name="frm_srch" action="index.cfm?p=srch" method="post">
                <table>
                    <tr>
                        <td>
                            <input type="text" name="word" id="word" value="#request.word#"><br>
                        </td>
                    </tr>
                    <tr>
                        <td>
                            <select name="chk" id="chk">
                            <option value=""></option>
                            <option value="0" <cfif request.chk eq 0>selected</cfif>>チェックなし</option>
                            <option value="1" <cfif request.chk eq 1>selected</cfif>>チェック済</option>
                            </select>
                        </td>
                    </tr>
                    <tr>
                        <td>
                            <input type="submit" value="検索">
                        </td>
                    </tr>
                </table>
                </form>
            <!-- /.menu --></div>
        <!-- /##left --></div>

        <!-- center -->
        <div id="center">
            <!-- content -->
            <div id="content">
                <h3>メモ</h3>

                <form name="frm_in" action="index.cfm?p=addEnd" method="post">
                    <input type="hidden" name="page"    value="1">
                    <input type="hidden" name="id"      value="">
                    <input type="hidden" name="i1"      value="">

                    <textarea name="m1" cols="70" rows="2" id="txt"></textarea>
                    <br>
                    <input type="submit" value="add">

                    <br>
                    <br>

                    <table border="1" id="list">

                        <tr>
                            <th>date</th>
                            <th>time</th>
                            <th>memo</th>
                        </tr>

                        <cfloop query="st.data">
                            <cfif st.data.i1 eq 0>
                                <tr>
                            </cfif>
                            <cfif st.data.i1 eq 1>
                                <tr style='background-color:red;color:white;'>
                            </cfif>

                                <td><a href="javascript:js_upd(#st.data.id#, #st.data.i1#)">#st.data.c1#</a></td>
                                <td>#st.data.c2#</td>
                                <td>#HTMLEditFormat(st.data.m1)#</td>
                            </tr>
                        </cfloop>
                    </table>
                    page:
                    <cfloop index="local.idx" from="1" to="#st.pageCount#">
                        <cfif local.idx eq url.page>
                            <strong>#local.idx#</strong>
                        <cfelse>
                            <a href="index.cfm?page=#local.idx#">#local.idx#</a>
                        </cfif>
                    </cfloop>
                </form>

            <!-- /##content --></div>
        <!-- /##center --></div>

        <div class="clearblock"/>

        <!-- footer -->
        <div id="footer">
            <form name="frm_cookie">
                <table border="0" width="100%">
                    <tr>
                        <td>user_id:<input type="text" name="user_id" id="user_id" value="#request.user_id#"></td>
                        <td>key:<input type="text" name="key" id="key" value="#request.key#"></td>
                        <td>
                            <input type="button" value="cookie change" onClick="js_cookie()">
                            <input type="button" value="cookie delete" onClick="js_cookie_del()">
                        </td>
                    </tr>
                </table>
            </form>
        <!-- /##footer --></div>
    <!-- /##container --></div>

    <script language="JavaScript">
    document.frm_in.m1.focus();
    </script>
    </body>
    </html>
    </cfoutput>
</cffunction>