めまぴークライアントのデモ４のソース

めまぴークライアントのデモ４の記事はこちらです。

■Application.cfm

<cfsetting enableCFoutputOnly="yes">

<cfapplication name="memapi_demo_4_sys"
    clientmanagement="Yes"
    sessionmanagement="yes"
    loginStorage="session"
    sessiontimeout=#CreateTimeSpan(1, 0, 0, 0)# >

<!---===================================
設定
====================================--->
<cfparam name="cookie.user_id"  default="">
<cfparam name="cookie.key"      default="">
<cfparam name="session.word"    default="">
<cfparam name="session.chk1"    default="c1">
<cfparam name="session.chk2"    default="c2">
<cfset request.user_id  = cookie.user_id>
<cfset request.key      = cookie.key>
<cfset request.word     = session.word>
<cfset request.chk1     = session.chk1>
<cfset request.chk2     = session.chk2>
<cfset request.cat_id   = 3>
<!--- 通常
<cfset request.proxyServer      = "">
<cfset request.proxyPort        = "80">
--->
<!--- 会社
<cfset request.proxyServer      = "xx.xx.xx.xx">
<cfset request.proxyPort        = "xx">
--->
<cfset request.proxyServer      = "">
<cfset request.proxyPort        = "80">
<cfset request.url              = "http://memapi.utalab.com/index.cfm?go=">

■index.cfm

<cfprocessingdirective pageEncoding = "UTF-8">
<!---/////////////////////////////////////////////////////////////////

複数登録、訂正、削除

//////////////////////////////////////////////////////////////////--->
<cfparam name="url.p"       default="">
<cfparam name="url.page"    default="1">
<cfparam name="url.id"      default="">

<cfparam name="form.id" default="#url.id#">
<cfparam name="form.c1" default="">
<cfparam name="form.c2" default="">
<cfparam name="form.c3" default="">
<cfparam name="form.c4" default="">
<cfparam name="form.c5" default="">
<cfparam name="form.m1" default="">

<cfswitch expression = "#url.p#">
    <!--- srch --->
    <cfcase value="srch">
        <cfset session.word = form.word>
        <cfset session.chk1 = form.chk1>
        <cfset session.chk2 = form.chk2>
        <cfset request.word = form.word>
        <cfset request.chk1 = form.chk1>
        <cfset request.chk2 = form.chk2>
    </cfcase>
    <!--- addEnd --->
    <cfcase value="addEnd">
        <cfhttp url="#request.url#dataAddExs"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">

            <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
            <cfhttpparam type="formField" name="key"        value="#request.key#">
            <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
            <cfhttpparam type="formField" name="id_list"    value="#form.id_list#">
            <cfloop index="idx" list="#form.id_list#">
                <cfhttpparam type="formField" name="c1_#idx#"   value="#form["c1_#idx#"]#">
                <cfhttpparam type="formField" name="c2_#idx#"   value="#form["c2_#idx#"]#">
                <cfhttpparam type="formField" name="c3_#idx#"   value="#form["c3_#idx#"]#">
            </cfloop>
        </cfhttp>
    </cfcase>
    <!--- updEnd --->
    <cfcase value="updEnd">
        <cfhttp url="#request.url#dataUpdExs"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">

            <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
            <cfhttpparam type="formField" name="key"        value="#request.key#">
            <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
            <cfhttpparam type="formField" name="id_list"    value="#form.id_list#">
            <cfloop index="idx" list="#form.id_list#">
                <cfhttpparam type="formField" name="c1_#idx#"   value="#form["c1_#idx#"]#">
                <cfhttpparam type="formField" name="c2_#idx#"   value="#form["c2_#idx#"]#">
                <cfhttpparam type="formField" name="c3_#idx#"   value="#form["c3_#idx#"]#">
            </cfloop>
        </cfhttp>

    </cfcase>
    <!--- delEnd --->
    <cfcase value="delEnd">
        <cfhttp url="#request.url#dataDelExs"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">

            <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
            <cfhttpparam type="formField" name="key"        value="#request.key#">
            <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
            <cfhttpparam type="formField" name="id_list"    value="#form.id_list#">
        </cfhttp>
    </cfcase>
</cfswitch>
<cfif findnocase("end", url.p)>
    <cflocation url="index.cfm" addtoken="no">
</cfif>

<cfset st = cst_getData("", url.page)>
<cfset fm = "">
<cfswitch expression = "#url.p#">
    <!--- add --->
    <cfcase value="add">
        <cfset form.id_list = "">
        <cfloop index="idx" from="0" to="9">
            <cfset form.id_list = ListAppend(form.id_list, idx)>
            <cfset form["c1_#idx#"] = "">
            <cfset form["c2_#idx#"] = "">
            <cfset form["c3_#idx#"] = "">
        </cfloop>
        <cfset fm = cst_fm(form.id_list)>
    </cfcase>
    <!--- upd --->
    <cfcase value="upd">
        <cfset sttmp = cst_getData(form.id_list)>
        <cfloop query="sttmp.data">
            <cfset form["c1_#sttmp.data.id#"]   = sttmp.data.c1>
            <cfset form["c2_#sttmp.data.id#"]   = sttmp.data.c2>
            <cfset form["c3_#sttmp.data.id#"]   = sttmp.data.c3>
        </cfloop>
        <cfset fm = cst_fm(form.id_list)>
    </cfcase>
</cfswitch>
<cfset cst_layout(st, fm)>
<!---=================================================================
cst_fm
==================================================================--->
<cffunction name="cst_fm" access="public" returnType="string" output="yes">
    <cfargument name="id_list" type="string" required="yes">

    <cfset var local = structNew()>

    <cfsavecontent variable = "local.tmp">
    <cfoutput>
    <form name="frm" method="post">
    <input type="hidden" name="id_list" value="#arguments.id_list#">
    <table>
        <tr>
            <th>氏名</th>
            <th>シメイ</th>
            <th>郵便番号</th>
        </tr>

        <cfloop index="local.idx" list="#arguments.id_list#">
            <tr>
                <td><input type="text" name="c1_#local.idx#" value="#form["c1_#local.idx#"]#"></td>
                <td><input type="text" name="c2_#local.idx#" value="#form["c2_#local.idx#"]#"></td>
                <td><input type="text" name="c3_#local.idx#" value="#form["c3_#local.idx#"]#"></td>
            </tr>
        </cfloop>
    </table>
    <cfif url.p eq "add">
        <input type="button" value="add" onClick="js_add()">
    </cfif>
    <cfif url.p eq "upd">
        <input type="button" value="upd" onClick="js_upd()">
        <input type="button" value="del" onClick="js_del()">
    </cfif>
    </form>
    <br>
    <script language="JavaScript">
    <!--
    function js_add(){
        with(document.frm){
            if(confirm("add OK?")){
                action = "index.cfm?p=addEnd";
                submit();
            }
        }
    }
    function js_upd(){
        with(document.frm){
            if(confirm("upd OK?")){
                action = "index.cfm?p=updEnd";
                submit();
            }
        }
    }
    function js_del(){
        with(document.frm){
            if(confirm("del OK?")){
                action = "index.cfm?p=delEnd";
                submit();
            }
        }
    }
    //-->
    </script>
    </cfoutput>
    </cfsavecontent>

    <cfreturn local.tmp>
</cffunction>
<!---=================================================================
cst_getData
==================================================================--->
<cffunction name="cst_getData" access="public" returnType="struct" output="no">
    <cfargument name="id_list" type="string" required="yes">
    <cfargument name="page" type="string" default="1">

    <cfhttp url         = "#request.url#dataGetEx"
            proxyServer = "#request.proxyServer#"
            proxyPort   = "#request.proxyPort#"
            method="post">

        <cfhttpparam type="formField" name="user_id"    value="#request.user_id#">
        <cfhttpparam type="formField" name="key"        value="#request.key#">
        <cfhttpparam type="formField" name="id_list"    value="#arguments.id_list#">
        <cfhttpparam type="formField" name="cat_id"     value="#request.cat_id#">
        <cfhttpparam type="formField" name="fil_id"     value="#request.chk2#">
        <cfhttpparam type="formField" name="fld_list"   value="id,cat_id,c1,c2,c3,c4,c5,m1">

        <cfif arguments.id_list eq "">
            <cfhttpparam type="formField" name="srch_fld"   value="#request.chk1#">
            <cfhttpparam type="formField" name="word"       value="#request.word#">
        </cfif>

        <cfhttpparam type="formField" name="row"        value="10">
        <cfhttpparam type="formField" name="page"       value="#arguments.page#">
        <cfhttpparam type="formField" name="type"       value="wddx">
        <cfhttpparam type="formField" name="debug"      value="">
    </cfhttp>

    <cfwddx action="wddx2cfml" input="#cfhttp.filecontent#" output="outData">

    <cfreturn outdata>
</cffunction>
<!---=================================================================
cst_layout
==================================================================--->
<cffunction name="cst_layout" access="public" returnType="void" output="yes">
    <cfargument name="stru" type="struct" required="yes">
    <cfargument name="frm" type="string" required="yes">

    <cfset var st = arguments.stru>
    <cfset var fm = arguments.frm>

    <cfoutput>
    <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
    <html xmlns="http://www.w3.org/1999/xhtml" lang="ja" xml:lang="ja">
    <head>
        <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
        <meta http-equiv="content-style-type" content="text/css; charset=utf-8" />
        <meta http-equiv="Content-Script-Type" content="text/javascript" />
        <title>めまぴークライアントのデモ（住所録）</title>
        <meta name="keywords" content="めまぴー,memapi" />
        <meta name="description" content="めまぴークライアントのデモ（住所録）です。" />
        <link href="common.css" rel="stylesheet" type="text/css" media="all" />
        <script type="text/javascript" src="common.js"></script>
        <script type="text/javascript" src="index.js"></script>
    </head>
    <body>
    <!-- container -->
    <div id="container">

        <!-- header -->
        <div id="header">
            <!-- left -->
            <div class="left">
                        <h1><a href="index.cfm" accesskey="1">めまぴークライアントのデモ（住所録）</a></h1>
                        <h2>by <a href="http://memapi.utalab.com/" target="_blank">めまぴー</a></h2>
            <!-- /.left --></div>

            <!-- right -->
            <div class="right">
            <!-- /.right --></div>

        <!-- /##header --></div>

        <div class="clearblock"/>

        <!-- left -->
        <div id="left">
            <!-- menu -->
            <div class="menu">
                <p class="title">STATUS</p>

                <table>
                    <tr>
                        <th>ret</th>
                        <td align="right" id="ret">#st.ret#</td>
                    </tr>
                    <tr>
                        <th>pageCount</th>
                        <td align="right" id="pageCount">#st.pageCount#</td>
                    </tr>
                    <tr>
                        <th>recCount</th>
                        <td align="right" id="recCount">#st.recCount#</td>
                    </tr>
                </table>

            <!-- /.menu --></div>

            <!-- menu -->
            <div class="menu">
                <p class="title">検索</p>

                <form name="frm_srch" action="index.cfm?p=srch" method="post">
                <table>
                    <tr>
                        <td>
                            <input type="text" name="word" id="word" value="#request.word#"><br>
                        </td>
                    </tr>
                    <tr>
                        <td>
                            <select name="chk1">
                            <option value="c1" <cfif request.chk1 eq "c1">selected</cfif>>氏名</option>
                            <option value="c2" <cfif request.chk1 eq "c2">selected</cfif>>シメイ</option>
                            <option value="c3" <cfif request.chk1 eq "c3">selected</cfif>>郵便番号</option>
                            <option value="c4" <cfif request.chk1 eq "c4">selected</cfif>>住所</option>
                            <option value="c5" <cfif request.chk1 eq "c5">selected</cfif>>電話番号</option>
                            <option value="m1" <cfif request.chk1 eq "m1">selected</cfif>>メモ</option>
                            </select>
                        </td>
                    </tr>
                    <tr>
                        <td>
                            <select name="chk2">
                            <option value="c2"      <cfif request.chk2 eq "c2">selected</cfif>>シメイ（昇順）</option>
                            <option value="c2_desc" <cfif request.chk2 eq "c2_desc">selected</cfif>>シメイ（降順）</option>
                            <option value="c3"      <cfif request.chk2 eq "c3">selected</cfif>>郵便番号（昇順）</option>
                            <option value="c3_desc" <cfif request.chk2 eq "c3_desc">selected</cfif>>郵便番号（降順）</option>
                            </select>
                        </td>
                    </tr>
                    <tr>
                        <td>
                            <input type="submit" value="検索">
                        </td>
                    </tr>
                </table>
                </form>
            <!-- /.menu --></div>

            <!-- menu -->
            <div class="menu">
                <p class="title">
                <input type="button" value="新規登録" onClick="js_entry()">
                </p>

            <!-- /.menu --></div>
        <!-- /##left --></div>

        <!-- center -->
        <div id="center">
            <!-- content -->
            <div id="content">
                <h3>住所録</h3>

                #fm#

                <form name="frm2" method="post">
                <table border="1" id="list">

                    <tr>
                        <th>&nbsp;</th>
                        <th>氏名</th>
                        <th>シメイ</th>
                        <th>郵便番号</th>
                    </tr>

                    <cfloop query="st.data">
                        <tr>
                            <td>
                                <input type="checkbox" name="id_list" id="chk_#st.data.currentRow#" value="#st.data.id#">
                            </td>
                            <td>#st.data.c1#</td>
                            <td>#st.data.c2#</td>
                            <td>#st.data.c3#</td>
                        </tr>
                    </cfloop>
                </table>
                page:
                <cfloop index="local.idx" from="1" to="#st.pageCount#">
                    <cfif local.idx eq url.page>
                        <strong>#local.idx#</strong>
                    <cfelse>
                        <a href="index.cfm?page=#local.idx#">#local.idx#</a>
                    </cfif>
                </cfloop>
                <br>
                <input type="button" value="upd" onClick="js_updForm()">
                </form>
                </br>
                <script language="JavaScript">
                <!--
                function js_updForm(){
                    with(document.frm2){
                        var isOK = false;
                        for(i=1;i<=#st.data.recordCount#;i++){
                            if(document.getElementById('chk_'+i).checked){
                                isOK = true;
                                break;
                            }
                        }
                        if(isOK){
                            action = "index.cfm?p=upd";
                            submit();
                        }else{
                            alert("チェックしてください！");
                        }
                    }
                }
                //-->
                </script>


            <!-- /##content --></div>
        <!-- /##center --></div>

        <div class="clearblock"/>

        <!-- footer -->
        <div id="footer">
            <form name="frm_cookie">
                <table border="0" width="100%">
                    <tr>
                        <td>user_id:<input type="text" name="user_id" id="user_id" value="#request.user_id#"></td>
                        <td>key:<input type="text" name="key" id="key" value="#request.key#"></td>
                        <td>
                            <input type="button" value="cookie change" onClick="js_cookie()">
                            <input type="button" value="cookie delete" onClick="js_cookie_del()">
                        </td>
                    </tr>
                </table>
            </form>
        <!-- /##footer --></div>
    <!-- /##container --></div>

    </body>
    </html>
    </cfoutput>
</cffunction>